Normally just a link will launch the Acrobat plugin right in the browser.
Recently though I had a client that wanted a message box tp pop up...this is achieved with a bit of asp, (not something I know much about since I hate MS languages)
This will give a box that gives the option of saving the file to the hard drive or opening it with Acrobat Reader.
*IF* you have asp enabled on the hosting server:
Open a plain text editor and paste this in changing the name of the .pdf file to your file name. (I have bolded it)
Give this file the same name as your pdf with an asp extention.
yourpdfname.asp (do not put .pdf here...if you .pdf is named brochure.pdf, then this would be brochire.asp)
Upload this file is ASCII format with your FTP program.
<%@Language="VBScript"%>
<%Option Explicit%>
<%Response.Buffer = True%>
<%
On Error Resume Next
Dim strPath
strPath = "nameofyourfile.pdf"
Call DownloadFile(strPath)
Private Sub DownloadFile(file)
'--declare variables
Dim strAbsFile
Dim strFileExtension
Dim objFSO
Dim objFile
Dim objStream
'-- set absolute file location
strAbsFile = Server.MapPath(file)
'-- create FSO object to check if file exists and get properties
Set objFSO = Server.CreateObject("Scripting.FileSystemObject")
'-- check to see if the file exists
If objFSO.FileExists(strAbsFile) Then
Set objFile = objFSO.GetFile(strAbsFile)
'-- first clear the response, and then set the appropriate headers
Response.Clear
'-- the filename you give it will be the one that is shown
' to the users by default when they save
Response.AddHeader "Content-Disposition", "attachment; filename=" & objFile.Name
Response.AddHeader "Content-Length", objFile.Size
Response.ContentType = "application/pdf"
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
'-- set as binary
objStream.Type = 1
Response.CharSet = "UTF-8"
'-- load into the stream the file
objStream.LoadFromFile(strAbsFile)
'-- send the stream in the response
Response.BinaryWrite(objStream.Read)
objStream.Close
Set objStream = Nothing
Set objFile = Nothing
Else 'objFSO.FileExists(strAbsFile)
Response.Clear
Response.Write("No such file exists.")
End If
Set objFSO = Nothing
End Sub
%>
Make sure this file is in the same directory as the pdf..
Oops..correction... the link is not normal it's:
<a href="filename.asp">Link Text</a>